#!/usr/bin/perl -w
# vim: set sw=4 ts=4 si et:
# Copyright: GPL, Author: Guido Socher
# For instructions see: sub help()
# Uses ImageMagick convert program:
# convert -geometry 450x450 image t_image
#
use strict;
use vars qw($opt_f $opt_h);
use Getopt::Std;
my %html;
my %file2htmlpage;
my @files;
my @pages;
my %pages2title;
my $title="";
my $file="";
my $tfile="";
my $ttfile="";
my $tdir="";
my $txt="";
my $name="";
my $today;
my $ver="0.3";
#
my $imageperpage=0;
my $pagecnt=0;
$today=&today();
&readHTMLpage;
#
&getopts("fh")||die "ERROR: No such option. -h for help\n";
&help if ($opt_h);
#
&help unless($ARGV[0]);
# The processing takes long time and it causes problems if
# the textfile is modified during that time. Therefore we read it at
# once: 
my @textfile;
open(FF,"$ARGV[0]")||die "ERROR: can not read file $ARGV[0]\n";
while(<FF>){
    next if (/^\s*\#/);
    push(@textfile,$_);
}
close FF;
foreach (@textfile){
    next unless (/\w/);
    if (/^== *(.+)/){
        $title=$1;
        # if we have already images on the current page then we close that
        # page
        if ($imageperpage){
            &printHTMLpage('tail');
            close OUT;
            $pagecnt++;
            $imageperpage=0;
        }
        next;
    }
    if (/^(\S+)\s*(.*)/){
        if ($2){
            $txt=$2;
            &htmlumlaute(\$txt);
        }else{
            $txt="";
        }
        $file=$1;
        # make realative file name:
        $file=~s/^\.\///;
        unless(-r "$file"){
            print STDERR "Warning: line $., can not read image $file, ignoring it\n";
            next;
        }
        if (-d "$file"){
            print STDERR "Warning: line $., $file is a directory, ignoring it\n";
            next;
        }
        if($file=~/_tt?\./){
            print STDERR "Warning: line $. : $file looks like a thumb nail, ignoring it\n";
            next;
        }
        unless($file=~/(\.jpg)|(\.gif)/i){
            print STDERR "Warning: line $. : $file is not jpg or gif, ignoring it\n";
            next;
        }
        #
        ($tfile,$tdir)=&tfile($file);
        ($ttfile,$tdir)=&ttfile($file);
        unless (-d "$tdir"){
            print "making directory $tdir\n";
            system("mkdir -p $tdir");
        }
        $name=$file;
        $name=~s/\W/_/g;
        if ($imageperpage==0){
            #first image
            open(OUT,">index_$pagecnt.html")||die "ERROR: can not write index_$pagecnt.html\n";
            push(@pages,"index_$pagecnt.html");
            if ($title){
                $pages2title{"index_$pagecnt.html"}=$title;
            }else{
                $pages2title{"index_$pagecnt.html"}="index_$pagecnt.html";
            }
            &printHTMLpage('head');
        }
        &printHTMLpage('thumbstart');
        &printHTMLpage('thumbstop');
        $imageperpage++;
        $file2htmlpage{$file}="index_$pagecnt.html#$name";
        push(@files,"$file");

        print STDOUT "$file\n";
        if (! -f "$tfile" || $opt_f){
            system("convert -geometry \"560x420>\" $file $tfile");
            # you can otherwise not crtl-c the program:
            sleep 1;
        }
        if (! -f "$ttfile" || $opt_f){
            system("convert -geometry 50x50 $file $ttfile");
            # you can otherwise not crtl-c the program:
            sleep 1;
        }
    }
}
if($imageperpage){
    &printHTMLpage('tail');
    close OUT;
}
my $all=0;
my $i=0;
for $file (@files){
    if ($i==0){
        open(OUT,">index_all$all.html")||die "ERROR: can not write index_all$all.html\n";
        &printHTMLpage('thumbonlyhead');
        print OUT "<TABLE width=600 CELLSPACING=2 CELLPADDING=0 BORDER=0>\n";
        print OUT "<tr>\n";
    }
    $i++;
    ($ttfile,$tdir)=&ttfile($file);
    print OUT "<td><a href=\"" . $file2htmlpage{$file} ."\"><img src=\"$ttfile\"></a></td>  ";
    if ($i % 5 == 0){
        print OUT "</tr>\n<tr>\n";
    }
    if ($i == 50 ){
        $all++;
        print OUT "\n</tr>\n</table>\n";
        print OUT "<p><a href=\"index_all$all.html\"><b>Next page</b></a></p>\n";
        &printHTMLpage('thumbonlytail');
        close OUT;
        $i=0;
    }
}
if ($i){
    print OUT "\n</tr>\n</table>\n";
    &printHTMLpage('thumbonlytail');
    close OUT;
}
#
# content page
if ($pagecnt){
    open(OUT,">index.html")||die "ERROR: can not write index.html\n";
    $title="Picture index";
    &printHTMLpage('contenthead');
    for $file (@pages){
        $tfile=$pages2title{$file};
        print OUT "<br><a href=\"$file\">$tfile</a>\n";
    }
    &printHTMLpage('contenttail');
    close OUT;
}else{
    system("cp index_0.html index.html");
}
system("cp index.html index.htm");
#--------------------------------------------------------
sub printHTMLpage($){
    my $reqpage = shift;
    my $t;
    die "ERROR: no such template $reqpage\n" unless ($html{$reqpage});
    for (@{$html{$reqpage}}){
        # must copy otherwise we change %html
        $t=$_;
        $t=~s/\$title/$title/;
        $t=~s/\$file/$file/g;
        $t=~s/\$tfile/$tfile/;
        $t=~s/\$ttfile/$ttfile/;
        $t=~s/\$name/$name/;
        $t=~s/\$txt/$txt/;
        $t=~s/\$today/$today/;
        $t=~s/\$ver/$ver/;
        print OUT $t;
    }
}
#--------------------------------------------------------
sub readHTMLpage(){
    #read and print any text between __ xxx __ and the next __ 
    my $pagename="nix";
    while(<DATA>){
        if (/^__ (\w+) __/){
            $pagename=$1;
            next;
        }
        next if (/^__ /);
        push(@{$html{$pagename}},$_);
    }
}
#--------------------------------------------------------
sub dirname($){
    my $file=shift;
    if ($file=~/\//){
        $file=~s/\/.*$//;
        return($file);
    }else{
        return ".";
    }
}
#--------------------------------------------------------
sub basename($){
    my $file=shift;
    $file=~s/^.*\///;
    $file;
}
#--------------------------------------------------------
# convert the file name xxx/yyy/zzz.jpg into xxx/yyy/zzz_t.jpg
sub tfile($){
    my $file=shift;
    my ($b,$d);
    $b=&basename($file);
    $b=~s/(\.\w+)$/_t$1/;
    $d=&dirname($file);
    ("thumbs/$d/$b","thumbs/$d");
}
#--------------------------------------------------------
# convert the file name xxx/yyy/zzz.jpg into xxx/yyy/zzz_tt.jpg
sub ttfile($){
    my $file=shift;
    my ($b,$d);
    $b=&basename($file);
    $b=~s/(\.\w+)$/_tt$1/;
    $d=&dirname($file);
    ("thumbs/$d/$b","thumbs/$d");
}
#--------------------------------------------------------
sub today{
    my @ltime = gmtime;
    my $today;
    $today =  sprintf("%04d-%02d-%02d",1900 + $ltime[5],$ltime[4] + 1,$ltime[3]);
    $today;
}
#--------------------------------------------------------
sub htmlumlaute($){
    my $txt_ptr=shift;
	$$txt_ptr=~s/¡/\&iexcl;/g;
	$$txt_ptr=~s/¿/\&iquest;/g;
	$$txt_ptr=~s/À/\&Agrave;/g;
	$$txt_ptr=~s/Á/\&Aacute;/g;
	$$txt_ptr=~s/Â/\&Acirc;/g;
	$$txt_ptr=~s/Ã/\&Atilde;/g;
	$$txt_ptr=~s/Ä/\&Auml;/g;
	$$txt_ptr=~s/Å/\&Aring;/g;
	$$txt_ptr=~s/Ç/\&Ccedil;/g;
	$$txt_ptr=~s/È/\&Egrave;/g;
	$$txt_ptr=~s/É/\&Eacute;/g;
	$$txt_ptr=~s/Ê/\&Ecirc;/g;
	$$txt_ptr=~s/Ë/\&Euml;/g;
	$$txt_ptr=~s/Ì/\&Igrave;/g;
	$$txt_ptr=~s/Í/\&Iacute;/g;
	$$txt_ptr=~s/Î/\&Icirc;/g;
	$$txt_ptr=~s/Ï/\&Iuml;/g;
	$$txt_ptr=~s/Ñ/\&Ntilde;/g;
	$$txt_ptr=~s/Ò/\&Ograve;/g;
	$$txt_ptr=~s/Ó/\&Oacute;/g;
	$$txt_ptr=~s/Ô/\&Ocirc;/g;
	$$txt_ptr=~s/Õ/\&Otilde;/g;
	$$txt_ptr=~s/Ö/\&Ouml;/g;
	$$txt_ptr=~s/Ø/\&Oslash;/g;
	$$txt_ptr=~s/Ù/\&Ugrave;/g;
	$$txt_ptr=~s/Ú/\&Uacute;/g;
	$$txt_ptr=~s/Û/\&Ucirc;/g;
	$$txt_ptr=~s/Ü/\&Uuml;/g;
	$$txt_ptr=~s/Ý/\&Yacute;/g;
	$$txt_ptr=~s/ß/\&szlig;/g;
	$$txt_ptr=~s/à/\&agrave;/g;
	$$txt_ptr=~s/á/\&aacute;/g;
	$$txt_ptr=~s/â/\&acirc;/g;
	$$txt_ptr=~s/ã/\&atilde;/g;
	$$txt_ptr=~s/ä/\&auml;/g;
	$$txt_ptr=~s/å/\&aring;/g;
	$$txt_ptr=~s/æ/\&aelig;/g;
	$$txt_ptr=~s/ç/\&ccedil;/g;
	$$txt_ptr=~s/è/\&egrave;/g;
	$$txt_ptr=~s/é/\&eacute;/g;
	$$txt_ptr=~s/ê/\&ecirc;/g;
	$$txt_ptr=~s/ë/\&euml;/g;
	$$txt_ptr=~s/ì/\&igrave;/g;
	$$txt_ptr=~s/í/\&iacute;/g;
	$$txt_ptr=~s/î/\&icirc;/g;
	$$txt_ptr=~s/ñ/\&ntilde;/g;
	$$txt_ptr=~s/ò/\&ograve;/g;
	$$txt_ptr=~s/ó/\&oacute;/g;
	$$txt_ptr=~s/ô/\&ocirc;/g;
	$$txt_ptr=~s/ö/\&ouml;/g;
	$$txt_ptr=~s/ù/\&ugrave;/g;
	$$txt_ptr=~s/ú/\&uacute;/g;
	$$txt_ptr=~s/û/\&ucirc;/g;
	$$txt_ptr=~s/ü/\&uuml;/g;
}
#--------------------------------------------------------
sub help{
print "htmlpictures -- make a nice webpage with images
USAGE: htmlpictures [-hf] text-file

The text file contains a list of the images. This list can
e.g be generated with find . -print > text-file 

The text file has to have the following syntax:
filename optinal textual description
== title
filename2 optinal textual description
...

The textual description will appear besides the image on the webpage.
The line == title starts a new webpage for all following images and
give the webpage the specified title.

OPTIONS:
    -h this help
    -f force generation of thumb images even if they already exist
       (normally images are not regenerated when you run it a second time)
\n";
exit;
}
#--------------------------------------------------------
__END__ 

__ thumbonlytail __
<!-- start of footer -->
</BODY>
</HTML>

__ thumbonlyhead __
<HTML>
<HEAD>
 <META http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
 <TITLE>total index of all images</TITLE>
</HEAD>
<BODY>
<table align="right" border=0>
<tr>
    <td><a href="index.html">content</a></td>
    <td><a href="index_all0.html">Go to total picture index</a></td>
</tr></table>
<br clear="all">
<p>This is an overview with the first 50 images. Click on the image
to get to the respecitve page. If there are more than 50 images then
you can select the next overview page at the bottom of this page.</p>
<br clear="all">

__ contenttail __
<!-- start of footer -->
<hr WIDTH="80%" noshade="noshade" size="1">
 <CENTER> 
<table WIDTH="75%" >
 <TR bgcolor="#999999">
   <TD align="center">
   <FONT color="#FFFFFF">
    Generated by htmlpictures $ver, $today<BR>
    </FONT>
   </TD>
 </TR>
</TABLE>
</CENTER>
</BODY>
</HTML>

__ contenthead __
<HTML>
<HEAD>
 <META http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
 <TITLE>$title</TITLE>
</HEAD>
<BODY bgcolor="#26293f"  text="#FFFFFF" alink="#FF00FF" link="#FFA500" vlink="#FF7F50">
<table align="right" border=0>
<tr>
    <td><a href="index_all0.html">Go to total picture index</a></td>
</tr></table>
<br clear="all">
<center><h1>$title</h1></center>
<br clear="all">

__ tail __
<br clear="all">
<table align="right" border=0>
<tr>
    <td><a href="index.html">content</a></td>
</tr></table>
<!-- start of footer -->
<hr WIDTH="80%" noshade="noshade" size="1">
 <CENTER> 
<table WIDTH="75%" >
 <TR bgcolor="#999999">
   <TD align="center">
   <FONT color="#FFFFFF">
    Generated by htmlpictures $ver, $today<BR>
    </FONT>
   </TD>
 </TR>
</TABLE>
</CENTER>
</BODY>
</HTML>

__ head __
<HTML>
<HEAD>
 <META http-equiv="Content-Type" content="text/html; charset=iso-8859-1">
 <TITLE>$title</TITLE>
</HEAD>
<BODY bgcolor="#26293f"  text="#FFFFFF" alink="#FF00FF" link="#FFA500" vlink="#FF7F50">
<table align="right" border=0>
<tr>
    <td><a href="index.html">content</a></td>
    <td><a href="index_all0.html">Go to total picture index</a></td>
</tr></table>
<br clear="all">
<center><h1>$title</h1></center>
<br clear="all">

__ thumbstop __
</TD>
</TR>
</Table>
<!-- end of $file -->
<BR clear="all">

__ thumbstart __
<TABLE width=620 bgcolor="#2d395c" align="center">
<TR>
<TD>
<a name="$name">&nbsp;</a>
<table border=0>
<tr>
<td>
<font size="1"><a href="$file">$file</a><br>
<a href="$file"><img src="$tfile" alt="$file" align="left" hspace=10></a>
</font>
</td>
<td>
$txt
</td>
</tr>
</table>

__ ende __